ECON 321 Assignment 14: Cournot Merger

Market inverse demand is 8-Q, where Q is the total quantity produced.

For the “inside” firm that results from the merger of k firms and receives synergy x, the profit function is

profitI=((8-(Subscript[q, i])-(Subscript[q, -i]))-(1-x))(Subscript[q, i])

FOCI=D[profitI,(Subscript[q, i])]==0

For each of the outside firms, the profit function is

profitO=((8-(Subscript[q, o])-(Subscript[q, -o]))-1)(Subscript[q, o])

FOCO=D[profitO,(Subscript[q, o])]==0

We know that all the outside firms act the same, so the total output other than firm I must be

(Subscript[q, -i])=(n-k)(Subscript[q, o])

And from the perspective of the one O firm we have modeled, the total output other than itself is the output of the I firm plus the output of the other n-k-1 O firms

(Subscript[q, -o])=(Subscript[q, i])+(n-k-1)(Subscript[q, o])

Having defined those total quantities, the first order conditions now read

{FOCI,FOCO}

And now we can just solve simultaneously to get the Cournot-Nash equilibrium

qstars=Solve[{FOCI,FOCO},{(Subscript[q, i]),(Subscript[q, o])}]//Flatten

The total quantity, price, and profits in Cournot equilibrium are

totalquantity=((Subscript[q, i])+(n-k)(Subscript[q, o]))/.qstars//Simplify

{pstar=(8-totalquantity),profitIstar=profitI/.qstars,profitOstar=profitO/.qstars}//Simplify

How Profitable is a Merger of 2 Firms?

Now let’s look at whether the merger is profitable. That requires comparing the ex ante profits of the 2 merging firms to what they get after the merger.

{exanteprofits=profitIstar+profitOstar/.{x->0,k->1},mergedprofitsI=profitIstar/.{k->2}}//Simplify

This means anything more than a 2 to 1 merger without synergy is not profitable, as seen in the following graph

Plot[{exanteprofits,mergedprofitsI/.{x->0}},{n,2,6},PlotLabels->Automatic,AxesLabel->Automatic,PlotTheme->"Monochrome"]

If the synergy x is good enough, which means x high enough, it should be profitable to merge

profitEqualizingX=x/.Solve[exanteprofits==mergedprofitsI,x]//FullSimplify

profitEqualizingX/.n->5//N

Plot[profitEqualizingX[[2]],{n,2,7},PlotLabels->"Expressions",AxesLabel->Automatic,PlotRange->{-.2,.4},PlotTheme->"Monochrome"]

Now let’s calculate the consumer surplus. That’s just area under demand and above the Cournot equilibrium price:

CS=(1/2)(8-pstar)(totalquantity)

And total welfare before and after the merger is CS plus the total amount of profit

{exanteTW=(CS+n*profitOstar)/.{k->1,x->0},mergedTW=(CS+profitIstar+(n-k)profitOstar)/.k->2}

So what x makes CS the same and TW the same in a 2-firm merger?

CSequalizingX=x/.Solve[(CS/.{k->1,x->0})==(CS/.k->2),x]//Flatten

TWequalizingX=x/.Solve[exanteTW==mergedTW,x]//FullSimplify//Flatten

Evaluate for n=5 just to see which of the above solutions is the right one to use.

{CSequalizingX,TWequalizingX}/.n->5//N

Hmm, that didn’t help because those aren’t sensible values for x. Let’s try a much higher number of firms.

{CSequalizingX,TWequalizingX}/.n->10//N

Plot[{profitEqualizingX[[2]],CSequalizingX[[1]],TWequalizingX[[1]],1},{n,2,7},PlotLabels->Automatic,PlotRange->{-.1,1.2},AxesLabel->{"n","x"},PlotTheme->"Monochrome"]

The synergies from a merger need to be higher than the solid line for the merger to be worthwhile for the merging firms. Note that a 3 to 2 merger might produce enough synergies to be profitable and yet not enough to increase total welfare. If a 4 to 3 merger is profitable, it will definitely increase total welfare. But there need to be 7 firms for even the possibility of increasing consumer surplus to come into play.