ECON 321 Assignment 16: Entry-Related Strategies

Two firms both have the following market demand and individual cost functions

inversedemand = 20-Q

cost = 9+4*q

The firms play a two-period game by 4 different sets of rules as discussed below.

1. Firm 1  has a monopoly in both periods.

Then it' s enough just to solve the profit max problem for the first period :

inversedemandP1 = inversedemand/.Q->(Subscript[q, 1])

cost1 = cost /. q->(Subscript[q, 1])

profit1P1 = inversedemandP1*(Subscript[q, 1])-cost1//Simplify

FOC1P1 = D[profit1P1,(Subscript[q, 1])]==0

qstar1P1=Solve[FOC1P1,(Subscript[q, 1])]//Flatten//First

pstarP1=inversedemandP1/.qstar1P1

profitstar1P1 = profit1P1/.qstar1P1

2. In period 2, firm 2 observes a commitment by firm 1 to (Subscript[q, 1]).

inversedemandP2 = inversedemand/.Q->(Subscript[q, 1])+(Subscript[q, 2])

cost2=cost/.q->(Subscript[q, 2])

profit2P2=inversedemandP2*(Subscript[q, 2])-cost2

FOC2P2 = D[profit2P2,(Subscript[q, 2])]==0

react2P2=Solve[FOC2P2,(Subscript[q, 2])]//Flatten//First

profit2P2react=profit2P2/.react2P2//Simplify

3. Firm 1 Accommodates Firm 2

Firm 1 commits to the same quantity in both periods. Then Firm 1’s period 1 and 2 profits are

profit1P1

profit1P2=inversedemandP2*(Subscript[q, 1])-cost1//Expand

Firm 1 anticipates Firm 2’s reaction when it calculates its own profit function

profit1P2expected = profit1P2/.react2P2//Simplify

Firm 1 maximizes the sum of period 1 profits plus period 2 expected profits

profit1Both = profit1P1+profit1P2expected

FOC1Both=D[profit1Both,(Subscript[q, 1])]==0

qstar1Both = Solve[FOC1Both,(Subscript[q, 1])]//Flatten//First

Firm 1 sets the same quantity whether it has a monopoly or is accommodating entry.

Plot[{2*profit1P1,profit1Both},{(Subscript[q, 1]),0,12},PlotLabels->Automatic]

Then the period 2 outcomes under accommodation are

qstar2P2Acc = (Subscript[q, 2])/.react2P2/.qstar1Both

pstarP2Acc=inversedemandP2/.react2P2/.qstar1Both

profitstar2P2Acc=profit2P2react/.qstar1Both

profitstar1P2Acc=profit1P2/.react2P2/.qstar1Both

profitstar1BothAcc = profit1Both/.qstar1Both

4. Deter Entry?

First we need to find the level of (Subscript[q, 1]) that pushes Firm 2’s profits to 0

q1Deter=Solve[(profit2P2react)==0,(Subscript[q, 1])]//Flatten//N

Plot[(profit2P2react),{(Subscript[q, 1]),0,15},AxesLabel->Automatic]

So it’s the first solution. Then we just need to see whether this deterrence strategy is more profitable than the accommodation strategy:

profit1P1/.q1Deter[[1]]

profit1P2/.q1Deter[[1]]/.(Subscript[q, 2])->0

profit1BothDet=(profit1P1/.q1Deter[[1]])+(profit1P2/.q1Deter[[1]]/.(Subscript[q, 2])->0)

So deterrence is profitable in this case. Notice that it distorts the “capital investment” (Subscript[q, 1]) upward. This is a Cournot game in period 2, hence a game of strategic substitutes. The investment is hurtful to firm 2, so investment is tough. Thus in the case of deterrence this is a top dog strategy.

Entry Accommodation and Deterrence with Bertrand Competition

Stage 2: Bertrand Competition or Monopoly

demandM=20-2(Subscript[p, 1])

demand1=10-2(Subscript[p, 1])+(Subscript[p, 2])

demand2=10-2(Subscript[p, 2])+(Subscript[p, 1])

If monopoly

profitM=((Subscript[p, 1])-(Subscript[c, 1]))demandM

FOCM=D[profitM,(Subscript[p, 1])]==0

pstarM=Solve[FOCM,(Subscript[p, 1])]//Flatten//First

profitstarM=profitM/.pstarM//Simplify

If duopoly

{profit1=((Subscript[p, 1])-(Subscript[c, 1]))demand1,profit2=((Subscript[p, 2])-3)demand2}

FOCsD={D[profit1,(Subscript[p, 1])]==0,D[profit2,(Subscript[p, 2])]==0}

pstarsD=Solve[FOCsD,{(Subscript[p, 1]),(Subscript[p, 2])}]//Flatten

profitsstarD={profit1,profit2}/.pstarsD//FullSimplify

{profitstarM,profitsstarD}/.(Subscript[c, 1])->3//N

Stage 1: Firm 1 does R&D K to reduce (Subscript[c, 1])

stage1profit2=(profitsstarD[[2]]/.(Subscript[c, 1])->(3-K))-F

Accommodate Entry

stage1profit1=(profitsstarD[[1]]/.(Subscript[c, 1])->(3-K))-10(K^2)-F

Plot[stage1profit1/.F->9,{K,0,1}]

stage1FOC1=D[stage1profit1,K]==0

KstarAcc=Solve[stage1FOC1,K]//Flatten//N

stage1Profit1Acc=stage1profit1/.KstarAcc

stage1profit2/.KstarAcc

Blockade Entry

stage1profitM=(profitstarM/.(Subscript[c, 1])->(3-K))-10(K^2)-F

FOCblockade=D[stage1profitM,K]==0

KstarBlockade=Solve[FOCblockade,K]//Flatten//First//N

Fblockade=Solve[(stage1profit2/.KstarBlockade)==0,F]//Flatten//First

stage1Profit1Blockade=stage1profitM/.KstarBlockade

Deter Entry

KstarDeter=Solve[stage1profit2==0,K]//Flatten//Expand//N

Fdeter=Solve[(stage1profit1/.KstarAcc)==(stage1profitM/.KstarDeter),F][[1]]

stage1Profit1Deter=stage1profitM/.KstarDeter

Overall analysis: depending on fixed costs, it may be best to accommodate, deter, or it may just be possible to blockade.

Plot[{stage1Profit1Acc,stage1Profit1Deter,stage1Profit1Blockade},{F,8.5,12},PlotLabels->Automatic,PlotTheme->"Monochrome",GridLines->{{F/.Fblockade,F/.Fdeter},{}}]