ECON 321 Assignment 19: Two Networks on a Hotelling Line

Utility

As an addition to the assignment, let network 1 be slightly better by amount (Subscript[a, 1])

utility1=(60+(Subscript[a, 1]))-τ*x-(Subscript[p, 1])+(Subscript[n, 1])

utility2=60-τ(1-x)-(Subscript[p, 2])+(Subscript[n, 2])

Indifferent Consumer

Find the equation for the indifferent consumer who gets equal utility from the two networks

indiff=utility1==utility2

Now the number of users of each network must be (Subscript[n, 1])=x and (Subscript[n, 2])=(1-x) so we can substitute this into the formula for to get the "fulfilled expectations" equilibrium.

indiffFulfilled=indiff/.{(Subscript[n, 1])->x,(Subscript[n, 2])->(1-x)}

Now solve for the indifferent consumer in fulfilled expectations equilibrium.

xhat=x/.Solve[indiffFulfilled,x]//First

Network Profit Max and Reaction Functions

profits={(Subscript[p, 1])*xhat,(Subscript[p, 2])*(1-xhat)}

FOCs={D[profits[[1]],(Subscript[p, 1])]==0,D[profits[[2]],(Subscript[p, 2])]==0}//Simplify

reacts={Solve[FOCs[[1]],(Subscript[p, 1])],Solve[FOCs[[2]],(Subscript[p, 2])]}/.Rule->Equal//Flatten

Equilibrium Prices, Market Shares, and Profits

pstars=Solve[reacts,{(Subscript[p, 1]),(Subscript[p, 2])}]//Flatten//Simplify

xhatstar=xhat/.pstars//Simplify

profitstars =profits/.pstars//Simplify

Consumer Surplus at Equilibrium

The utility in equilibrium (net of price) of a network 1 consumer of type x

utilitystars={utility1,utility2}/.{(Subscript[n, 1])->x,(Subscript[n, 2])->(1-x)}/.pstars

and the CS is the utility (net of price) of all consumers between 0 and xhatstar for network 1 and between xhatstar and 1 for network 2

CS1=Integrate[utilitystars[[1]],{x,0,xhatstar}]//Simplify

CS2=Integrate[utilitystars[[2]],{x,xhatstar,1}]//Simplify

τ is the transport cost, it gets at how strongly people feel about the network’s stand-alone features as opposed to the network effect itself. One question is how does total consumer surplus (and also total profits) relate to τ. (To fit on the same graph nicely, add 57 to profits, actual profits are very low.)

Plot[{(CS1+CS2/.(Subscript[a, 1])->0),(57+Total[profitstars]/.(Subscript[a, 1])->0)},{τ,1,2},PlotLabels->Automatic]

Effects of (Subscript[a, 1]) Advantage

This is clearly a Bertrand game of strategic substitutes -- just look at the reaction functions. We can see what investment in (Subscript[a, 1])does to firm 2’s equilibrium profits:

D[profitstars[[2]],(Subscript[a, 1])]//FullSimplify

For reasonable values of (Subscript[a, 1]), this is negative, so investment makes firm 1 tough.

Second, if Network 1 were able to invest in raising (Subscript[a, 1]) we can parse out the effects. The direct effect, holding (Subscript[p, 2])constant, is

D[profits[[1]],(Subscript[a, 1])]

This is positive. The strategic effect has two components multiplied together:

{D[profits[[1]],(Subscript[p, 2])],D[(Subscript[p, 2])/.pstars,(Subscript[a, 1])]}

The overall strategic effect is negative because of the negative effect on firm 2’s optimal price. Thus we have a case where firm 1 would use the puppy dog strategy, underinvesting in (Subscript[a, 1]).

The advantage (Subscript[a, 1]), whether set strategically or exogenously, would also have interesting effects on consumer surplus:

Plot[{CS1/.τ->2,CS2/.τ->2},{(Subscript[a, 1]),0,1},PlotLabels->Automatic]

Plot[{CS1+CS2/.τ->2,(58+Total[profitstars]/.τ->2)},{(Subscript[a, 1]),0,1},PlotLabels->Automatic]