ECON 321 Assignment 6: Stackelberg

inverseDemand = 10-2((Subscript[q, 1])+(Subscript[q, 2]))

We solve backward for a subgame perfect Nash equilibrium. The Stage 2 subgame has firm 2 choosing its quantity given that (Subscript[q, 1]) is already known. Firm 2’s profit maximization problem and solution are

profit2=(inverseDemand-(Subscript[c, 2]))(Subscript[q, 2])

FOC2 = D[profit2,(Subscript[q, 2])]==0

react2=Solve[FOC2,(Subscript[q, 2])]//Flatten//First

Moving up to stage 1, firm 1 makes its choice of (Subscript[q, 1]). Firm 1 anticipates a Nash equilibrium in the subgame, so it expects firm 2 to behave optimally as we found above. Firm 1’s profit max and solution are

profit1=(inverseDemand-(Subscript[c, 1]))(Subscript[q, 1]) /.react2

FOC1 = D[profit1,(Subscript[q, 1])]==0

react1=Solve[FOC1,(Subscript[q, 1])]//Flatten//First

Then the subgame perfect Nash equilibrium outcome of the whole game is

{q1star,q2star}={(Subscript[q, 1]),(Subscript[q, 2])}/.react2/.react1 //Simplify

pstar = inverseDemand/.react2/.react1//Simplify

{profit1starStack,profit2starStack}={profit1,profit2}/.react2/.react1//Simplify

For the special case of (Subscript[c, 1])=(Subscript[c, 2])=1 the equilibrium outcomes are

{q1star,q2star,pstar,profit1starStack,profit2starStack} /. {(Subscript[c, 1])->1,(Subscript[c, 2])->1}//N

From Assignment 4, the Cournot outcome for the same demand function was (SuperStar[(Subscript[q, 1])])=(SuperStar[(Subscript[q, 2])])=1.5, (SuperStar[p])=4, and (SuperStar[(Subscript[π, 1])])=(SuperStar[(Subscript[π, 2])])=4.5. Thus, moving to Stackelberg has given firm 1 the chance to produce more than Cournot, force firm 2 to produce less than Cournot, and gain an advantage in profits of 5.06-4.5=0.56. Note, however, that the sum of total industry profits is lower than before, and price is 0.8125 the Cournot price, which means consumer surplus must be higher.

Extension: Compensate for Second Mover Disadvantage with a Cost Advantage

Suppose firm 1 has cost (Subscript[c, 1])=1, but firm 2 has some (Subscript[c, 2])<1. With a big enough advantage, firm 2 could earn as much as firm 1 even though it has to move second. We can find this by solving

Solve[((profit1starStack==profit2starStack)/.(Subscript[c, 1])->1),(Subscript[c, 2])]//N

Extension: Cost-Reducing R&D Followed by Cournot or Stackelberg

Consider the following game. In Stage 1, both firms simultaneously choose their costs but for any cost c they have to pay R&D cost ((((1/c)))^2). Then consider two alternatives: in stage 2 they play Cournot, or in stages 2a and 2b they play Stackelberg where firm 1 gets to move first. The question is which scenario induces more R&D to take place. If the Stage 2 Game is Cournot, then it solves like this:

profitsCournot={(inverseDemand-(Subscript[c, 1]))(Subscript[q, 1]),(inverseDemand-(Subscript[c, 2]))(Subscript[q, 2])}

FOCsCournot = {D[profitsCournot[[1]],(Subscript[q, 1])]==0,D[profitsCournot[[2]],(Subscript[q, 2])]==0}

qstarsCournot=Solve[FOCsCournot,{(Subscript[q, 1]),(Subscript[q, 2])}]//Flatten

profitstarCournot=profitsCournot/.qstarsCournot//Simplify

Then in Stage 1, the firms solve

stage1profitsCournot={profitstarCournot[[1]]-((((1/(Subscript[c, 1]))))^2),profitstarCournot[[2]]-((((1/(Subscript[c, 2]))))^2)}

We should check that these are nicely defined profit functions.

Plot[(stage1profitsCournot[[1]]/.(Subscript[c, 2])->1),{(Subscript[c, 1]),0,3}]

stage1FOCsCournot={D[stage1profitsCournot[[1]],(Subscript[c, 1])]==0,D[stage1profitsCournot[[2]],(Subscript[c, 2])]==0}

stage1cstarsCournot=Solve[stage1FOCsCournot,{(Subscript[c, 1]),(Subscript[c, 2])},Reals]//N

Element 1 is a symmetric solution. Let’s just check that the asymmetric solution is not a maximum.

Plot[(stage1profitsCournot[[1]]/.(Subscript[c, 2])->0.87),{(Subscript[c, 1]),0,7}]

If the Stage 2 game is Stackelberg, then the profits are exactly what we found in the assignment.

stage1profitsStack={profit1starStack-((((1/(Subscript[c, 1]))))^2),profit2starStack-((((1/(Subscript[c, 2]))))^2)}

{Plot[(stage1profitsStack[[1]]/.(Subscript[c, 2])->1),{(Subscript[c, 1]),0,3}],Plot[(stage1profitsStack[[2]]/.(Subscript[c, 1])->1),{(Subscript[c, 2]),0,3}]}

stage1FOCsStack={D[stage1profitsStack[[1]],(Subscript[c, 1])]==0,D[stage1profitsStack[[2]],(Subscript[c, 2])]==0}

stage1cstarsStack=Solve[stage1FOCsStack,{(Subscript[c, 1]),(Subscript[c, 2])},Reals]//N

{Plot[(stage1profitsStack[[1]]/.(Subscript[c, 2])->1.07),{(Subscript[c, 1]),0,3}],Plot[(stage1profitsStack[[1]]/.(Subscript[c, 2])->0.84),{(Subscript[c, 1]),0,7}]}

stage1cstarsStack=stage1cstarsStack[[2]]

So we have our answer: there is more incentive for firm 1 to do R&D under Stackelberg, but less incentive for firm 2. If we want to find out which outcome is better for consumers, we need to see what the equilibrium price is in each case

{inverseDemand/.qstarsCournot/.stage1cstarsCournot[[1]],inverseDemand/.react2/.react1/.stage1cstarsStack}

Price is 0.8113820 of Cournot price under Stackelberg. Without the stage 1 game Stackelberg price was 0.8125 of Cournot, so it appears the adding the R&D game has actually slightly helped consumer welfare. Actually, this is probably related to the market-share-weighted average of the costs, the same thing we talked about in Class 4. Let’s find those

quantityweightedcostsCour=((Subscript[q, 1])/((Subscript[q, 1])+(Subscript[q, 2])))*(Subscript[c, 1])+((Subscript[q, 2])/((Subscript[q, 1])+(Subscript[q, 2])))*(Subscript[c, 2])/.qstarsCournot/.stage1cstarsCournot[[1]]

quantityweightedcostsStack=((Subscript[q, 1])/((Subscript[q, 1])+(Subscript[q, 2])))*(Subscript[c, 1])+((Subscript[q, 2])/((Subscript[q, 1])+(Subscript[q, 2])))*(Subscript[c, 2])/.react2/.react1/.stage1cstarsStack